Initial commit

Forked from termo's demo-draw.c

1 files changed, 86 insertions, 0 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000..08ca44f
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,86 @@
+project (autistdraw C)
+cmake_minimum_required (VERSION 2.8.5)
+
+# Moar warnings
+if ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU" OR CMAKE_COMPILER_IS_GNUC)
+	set (CMAKE_C_FLAGS "-std=gnu99")
+	set (CMAKE_C_FLAGS_DEBUG
+		"${CMAKE_C_FLAGS_DEBUG} -Wall -Wextra -Wno-missing-field-initializers")
+endif ("${CMAKE_C_COMPILER_ID}" MATCHES "GNU" OR CMAKE_COMPILER_IS_GNUC)
+
+# Build options
+option (USE_SYSTEM_TERMO "Don't compile our own termo, use the system one" OFF)
+
+# Version
+set (project_VERSION_MAJOR "0")
+set (project_VERSION_MINOR "1")
+set (project_VERSION_PATCH "0")
+
+set (project_VERSION "${project_VERSION_MAJOR}")
+set (project_VERSION "${project_VERSION}.${project_VERSION_MINOR}")
+set (project_VERSION "${project_VERSION}.${project_VERSION_PATCH}")
+
+# Dependencies
+find_package (PkgConfig REQUIRED)
+pkg_check_modules (dependencies REQUIRED ncursesw libuv)
+
+if (USE_SYSTEM_TERMO)
+	find_package (Termo REQUIRED)
+else (USE_SYSTEM_TERMO)
+	add_subdirectory (termo EXCLUDE_FROM_ALL)
+	# We don't have many good choices when we don't want to install it and want
+	# to support older versions of CMake; this is a relatively clean approach
+	# (other possibilities: setting a variable in the parent scope, using a
+	# cache variable, writing a special config file with build paths in it and
+	# including it here, or setting a custom property on the targets).
+	get_directory_property (Termo_INCLUDE_DIRS
+		DIRECTORY termo INCLUDE_DIRECTORIES)
+	set (Termo_LIBRARIES termo-static)
+endif (USE_SYSTEM_TERMO)
+
+include_directories (${dependencies_INCLUDE_DIRS} ${Termo_INCLUDE_DIRS})
+
+# Configuration
+include (CheckFunctionExists)
+set (CMAKE_REQUIRED_LIBRARIES ${dependencies_LIBRARIES})
+CHECK_FUNCTION_EXISTS ("resize_term" HAVE_RESIZE_TERM)
+
+# Project source files
+set (project_sources ${PROJECT_NAME}.c)
+set (project_headers ${CMAKE_CURRENT_BINARY_DIR}/config.h)
+
+# Project libraries
+set (project_libraries ${dependencies_LIBRARIES} termo-static)
+
+# Generate a configuration file
+configure_file (${CMAKE_CURRENT_SOURCE_DIR}/config.h.in
+	${CMAKE_CURRENT_BINARY_DIR}/config.h)
+include_directories (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
+
+# Build the main executable and link it
+add_executable (${PROJECT_NAME} ${project_sources} ${project_headers})
+target_link_libraries (${PROJECT_NAME} ${project_libraries})
+
+# The files to be installed
+include (GNUInstallDirs)
+install (TARGETS ${PROJECT_NAME} DESTINATION ${CMAKE_INSTALL_BINDIR})
+install (FILES LICENSE DESTINATION ${CMAKE_INSTALL_DOCDIR})
+
+# CPack
+set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Terminal drawing application")
+set (CPACK_PACKAGE_VENDOR "Premysl Janouch")
+set (CPACK_PACKAGE_CONTACT "Přemysl Janouch <p.janouch@gmail.com>")
+set (CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
+set (CPACK_PACKAGE_VERSION_MAJOR ${project_VERSION_MAJOR})
+set (CPACK_PACKAGE_VERSION_MINOR ${project_VERSION_MINOR})
+set (CPACK_PACKAGE_VERSION_PATCH ${project_VERSION_PATCH})
+set (CPACK_GENERATOR "TGZ;ZIP")
+set (CPACK_PACKAGE_FILE_NAME
+	"${PROJECT_NAME}-${project_VERSION}-${CMAKE_SYSTEM_NAME}-${CMAKE_SYSTEM_PROCESSOR}")
+set (CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME}-${project_VERSION}")
+set (CPACK_SOURCE_GENERATOR "TGZ;ZIP")
+set (CPACK_SOURCE_IGNORE_FILES "/\\\\.git;/build;/CMakeLists.txt.user")
+set (CPACK_SOURCE_PACKAGE_FILE_NAME "${PROJECT_NAME}-${project_VERSION}")
+
+include (CPack)
+